home *** CD-ROM | disk | FTP | other *** search
/ PD Collection CD 1 / PD Collection CD 1.iso / textual / tex / files / !tex / mfinputs / greekl / mf
Encoding:
Text File  |  1988-02-26  |  21.8 KB  |  487 lines
  1. % This is GREEKL.MF in text format, as of Mar 31, 1986.
  2. % This lowercase Greek alphabet was prepared by D. E. Knuth in December, 1979,
  3. % inspired by the Monotype faces used in {\sl The Art of Computer Programming}.
  4. % (It has been designed for math formulas, not Greek texts.)
  5. % The programs were revised for the new \MF\ conventions in 1985.
  6.  
  7. % Character codes \0013--\0047 are generated.
  8.  
  9. cmchar "Lowercase Greek alpha";
  10. beginchar(oct"013",11u#,x_height#,0);
  11. italcorr max(1/3x_height#*slant+.5hair#+.5u#,x_height#*slant-.5u#);
  12. adjust_fit(0,0); pickup fine.nib;
  13. pos0(hair,0); pos1(vair,-90); pos2(curve,-180); pos3(vair,-270);
  14. z4=(w-3.25u,9/16h); z5=(w-2.75u,.5[vair,y4]);
  15. numeric theta; theta=angle(z4-z5)-90;
  16. pos4(stem,theta); pos5(stem,theta);
  17. pos6(vair,90); pos7(hair,180);
  18. rt x0r=hround(w-u); x1=x3=.5w-u; lft x2r=hround(1.5u-.5curve);
  19. x6=w-u; x7+.5hair=hround(w+.5hair-epsilon);
  20. top y0=vround .8[bar_height,h]; bot y1r=bot y6l=-oo;
  21. y2=.5[y1,y3]; top y3r=h+oo; y7=1/4bar_height;
  22. filldraw stroke z0e{down}...pulled_arc.e(1,2) & pulled_arc.e(2,3)
  23.  ...z4e---z5e...z6e{right}...{up}z7e; % diagonal, bowl, and hook
  24. math_fit(-.3x_height#*slant+.5curve#-u#,1/3x_height#*slant+.5hair#+.5u#);
  25. penlabels(0,1,2,3,4,5,6,7); endchar;
  26.  
  27. cmchar "Lowercase Greek beta";
  28. beginchar(oct"014",9.5u#,asc_height#,desc_depth#);
  29. italcorr .5[x_height#,asc_height#]*slant-u#;
  30. adjust_fit(0,0); pickup fine.nib;
  31. pos0(hair,180); pos1(hair,180); pos2(vair,90);
  32. pos3(stem,0); pos4(vair,-90); pos5(hair,-180);
  33. pos6(vair,-270); pos7(curve,-360); pos8(vair,-450); pos9(hair,-540);
  34. x0=x1=x9; lft x0l=hround(1.5u-.5hair); x2=x4=x6=x8=.5w+.25u;
  35. rt x3r=hround(w-1.5u); rt x7r=hround(w-1.5u+.5curve); rt x5l=hround(x4-u);
  36. bot y0=-d; y1=top y6r=x_height; top y2r=h+oo; y3=.5[y2,y4];
  37. y5=.5[y4,y6]; top y6r-bot y4r=vstem+eps; bot y8=-oo; y7=y9=.5[y6,y8];
  38. if y6l<y4l: y6l:=y4l:=y5; fi
  39. filldraw stroke z0e---z1e...pulled_arc.e(2,3)
  40.  & pulled_arc.e(3,4)...{up}z5e;  % stem and upper bowl
  41. filldraw stroke z5e{up}...pulled_arc.e(6,7)
  42.  & pulled_arc.e(7,8)...{up}z9e;  % lower bowl
  43. math_fit(desc_depth#*slant+.5hair#-u#,.7x_height#*slant+.5curve#-1.5u#);
  44. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  45.  
  46. cmchar "Lowercase Greek gamma";
  47. beginchar(oct"015",10u#,x_height#,desc_depth#);
  48. italcorr x_height#*slant-.5u#;
  49. adjust_fit(0,0); pickup fine.nib;
  50. pos1(hair,180); pos2(vstem+dw,90);
  51. pos4(hair,0); pos5(vair,-90); pos6(hair,-180); pos7(hair,-180);
  52. bot y1=.5772156649h; top y2r=h+oo; y4=y6=-.5d;
  53. bot y5r=-d-o; top y7=h;
  54. lft x1r=hround(.5u-.5hair); x2=3u; rt x4r=hround(w-2u); x5=.5[x4,x6];
  55. rt x4r-lft x6r=hround 1/3[hair,stem]+eps; rt x7l=hround(w-u);
  56. if x4l<x6l: x4l:=x6l:=x5; fi
  57. pos3(hair,angle(z4-z2)+90); x3=superness[x2,x4]; y3=superness[y4,y2];
  58. filldraw stroke z1e{up}...z2e{right}...z3e{z4-z2}
  59.  ...z4e{down}...{left}z5e; % arc
  60. filldraw stroke z5e{left}...z6e{up}..{2(x7-x6),y7-y6}z7e;  % stem
  61. math_fit(-.5772156649x_height#*slant,ic#-u#);
  62. penlabels(1,2,3,4,5,6,7); endchar;
  63.  
  64. cmchar "Lowercase Greek delta";
  65. beginchar(oct"016",8u#,asc_height#,0);
  66. italcorr .9asc_height#*slant+.5hair#-1.5u#;
  67. adjust_fit(0,0); pickup fine.nib;
  68. pos1(hair,-180); pos2(vair,-90);
  69. numeric theta; theta=angle(18u,-h);
  70. pos3(stem,theta+90); pos4(stem,theta+90); pos5(1/4[hair,stem],20);
  71. pos6(vair,-90); pos7(curve,-180); pos8(vair,-270);
  72. rt x1l=hround(w-2u+.5hair); x2=.5w; x3r=3u; rt x5r=hround(w-u);
  73. x4=x6=x8=.5w+.5u; lft x7r=hround(1.5u-.5curve);
  74. top y2l=h+oo; y1=min(.9h,y2r-eps); top y8r=x_height+oo; y4=y8;
  75. z4-z3=whatever*(18u,-h); y5=y7=.5[y6,y8]; bot y6=-oo;
  76. filldraw stroke z1e{x2-x1,3(y2-y1)}...z2e{left}...z3e---z4e
  77.  ....z5e{down}...pulled_arc.e(6,7) & pulled_arc.e(7,8);  % hook and bowl
  78. math_fit(-.3x_height#*slant+.5curve#-u#,.7x_height#*slant-.5u#);
  79. penlabels(1,2,3,4,5,6,7,8); endchar;
  80.  
  81. cmchar "Lowercase Greek epsilon";
  82. beginchar(oct"017",8u#,x_height#,0);
  83. italcorr x_height#*slant+.5hair#-2u#;
  84. adjust_fit(0,0); pickup fine.nib;
  85. pos0(bar,90); pos1(bar,90); pos2(curve,180);
  86. pos3(vair,270); pos4(hair,300); pos6(bar,90); pos7(bar,90);
  87. x1=.5w+.5u; x0=x1+u; lft x2r=hround(1.5u-.5curve); x3=.5[x0,x1];
  88. x4r=good.x(w-u); x5=w+.5u; x6=x0; z7=z2l;
  89. top y0r=top y1r=h; y2=y5=y6=bar_height; bot y3r=-oo;
  90. path p; p=z3r{right}...{up}z5;
  91. numeric t; t=ypart(((x4r,y3r)--(x4r,y5))intersectiontimes p);
  92. y4r=ypart point t of p;
  93. filldraw circ_stroke z0e..pulled_arc.e(1,2) & pulled_arc.e(2,3)
  94.  ...z4e{direction t of p};  % arc
  95. filldraw circ_stroke z6e--z7e;  % bar
  96. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  97. penlabels(0,1,2,3,4,5,6,7); endchar;
  98.  
  99. cmchar "Lowercase Greek zeta";
  100. beginchar(oct"020",9u#,asc_height#,desc_depth#);
  101. italcorr .75[x_height#,asc_height#]*slant-1.5u#;
  102. adjust_fit(0,0); pickup fine.nib;
  103. pos0(hair,-360); pos1(vair,-270); pos2(hair,-180); pos3(vair,-90);
  104. numeric theta; theta=90-angle(25u,x_height); slope:=-x_height/25u;
  105. pos6(stem,theta); pos7(vair,-90); pos8(vair,-135);
  106. lft x0l=hround 3.5u; x1=x3=.5[x0,x2]; rt x2l=hround max(rt x0r,w-2u)+eps;
  107. top y0=h; top y3l=bot y1l+vstem+eps=vround(y0-.25(h-x_height)); y2=.5[y1,y3];
  108. if y1r>y3r: y1r:=y3r:=y2; fi
  109. lft x4l=hround u; x4r-x4l=(hround .6[vair,stem])-fine;
  110. x6+.5u=x7=w-2u; x8=.5w+.75u;
  111. y6=-.1d; y8=-3/4d-oo; bot y7r=-d-oo;
  112. ellipse_set(3l,4l,5l,6l); ellipse_set(3r,4r,5r,6r);
  113. y4l:=.9[y6,y4l]; y4=y4r:=.9[y6,y4r];
  114. filldraw circ_stroke z0e{down}...z1e{right}...{up}z2e;  % opening hook
  115. filldraw circ_stroke z8e{x7-x8,2(y7-y8)}...z7e{right}
  116.  ...z6e---z5e....{up}z4e
  117.  ..tension 1 and atleast1.5..{right}z3e...{down}z2e;  % main stroke
  118. math_fit(-.2asc_height#*slant-.5u#,0);
  119. penlabels(0,1,2,3,4,5,6,7,8); endchar;
  120.  
  121. cmchar "Lowercase Greek eta";
  122. beginchar(oct"021",9u#,x_height#,desc_depth#);
  123. italcorr .8x_height#*slant+.5stem#-u#;
  124. adjust_fit(0,0); pickup fine.nib;
  125. x0=0; x1=x2; pos2(stem,0); lft x2l=hround(2.5u-.5stem); y2-.5stem=-oo;
  126. hook_in(0,a,1);  % opening hook
  127. filldraw circ_stroke z2e--z1e;  % left stem
  128. x4+.5stem=hround(w-1.5u+.5stem); ital_arch(2,3,4);  % arch
  129. pos5(stem,0); x5=x4; y5-.5stem=-d-o;
  130. filldraw circ_stroke z5e--z4e;  % right stem
  131. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#-1/3x_height#*slant);
  132. penlabels(0,a,1,2,3,4,5); endchar;
  133.  
  134. cmchar "Lowercase Greek theta";
  135. beginchar(oct"022",8.25u#,asc_height#,0);
  136. italcorr .7asc_height#*slant+.5curve#-u#;
  137. adjust_fit(0,0); pickup fine.nib;
  138. pos1(vair,90); pos2(curve,180); pos3(vair,270); pos4(curve,360);
  139. x1=x3=.5w; lft x2r=hround(1.5u-.5curve); x4=w-x2;
  140. top y1r=h+oo; y2=y4=.5[y1,y3]; bot y3r=-oo;
  141. filldraw stroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
  142.  & pulled_arc.e(3,4) & pulled_arc.e(4,1);  % bowl
  143. pos2'(bar,90); pos4'(bar,90); z2'=z2l; z4'=z4l;
  144. filldraw stroke z2'e--z4'e;  % bar
  145. math_fit(-.3asc_height#*slant-u#+.5curve#,ic#-.5u#);
  146. penlabels(1,2,3,4); endchar;
  147.  
  148. cmchar "Lowercase Greek iota";
  149. beginchar(oct"023",5u#,x_height#,0);
  150. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  151. adjust_fit(if monospace: u#,u# else: 0,0 fi); pickup fine.nib;
  152. pos1(stem,0); lft x1l=hround(1.5u-.5stem); y1+.5stem=h+oo;
  153. x2=x1-.25u; x4=w; hook_out(2,3,4)(skewed);  % closing hook
  154. filldraw circ_stroke z1e{down}...{-u,-x_height}z2e;  % stem
  155. math_fit(0,ic#); penlabels(1,2,3,4); endchar;
  156.  
  157. cmchar "Lowercase Greek kappa";
  158. beginchar(oct"024",9u#,x_height#,0);
  159. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  160. adjust_fit(0,0); pickup fine.nib;
  161. pos1(stem,0); pos2(stem,0); pos3(vair,90); pos4(vair,90); pos5(flare,90);
  162. x1=x2=x3; lft x1l=hround(1.5u-.5stem); y1+.5stem=h+oo; y2-.5stem=-oo;
  163. filldraw z1l---z2l..z2r---z1r..cycle;  % stem
  164. y3=bar_height; top y4r=h; x4+.5flare=hround(w-1.5u); z5r=z4r;
  165. path p,q; p=z3l{right}..{right}z4l; q=z5r{right}..z5l{left}...cycle;
  166. numeric t; t=ypart(p intersectiontimes q);
  167. filldraw stroke z3e{right}..{right}z4e;  % upper diagonal
  168. filldraw subpath(0,t) of q--cycle;  % bulb
  169. pos7(stem,0); pos8(vair,90); pos9(hair,180);
  170. x9+.5hair=hround(w+.5hair-epsilon); y9=1/3x_height;
  171. lft x7l=hround(w-2.75u-.5stem); y7=1/2y3; x8=w-1.2u; bot y8l=-oo;
  172. filldraw stroke z3e{right}...z7e{down}
  173.  ...z8e{right}...{up}z9e;  % lower diagonal
  174. math_fit(0,ic#); penlabels(1,2,3,4,5,7,8,9); endchar;
  175.  
  176. cmchar "Lowercase Greek lambda";
  177. beginchar(oct"025",10.5u#,asc_height#,0);
  178. adjust_fit(0,0); pickup fine.nib;
  179. pos1(vair,90); lft x1=hround .1u; top y1r=h;
  180. x2=x1+2u; y2=.7[x_height,h]; x3=w-2u; bot y4=-oo; y3=max(.07h,y4+eps);
  181. z4-(.25u,0)=whatever[z2,z3]; numeric theta; theta=angle(z2-z3)-90;
  182. pos2(stem,theta); pos3(stem,theta); pos4(stem,0);
  183. filldraw circ_stroke z1e{right}...z2e---z3e
  184.  ...{2(x4e-x3e),y4e-y3e}z4e;  % long diagonal
  185. y5=.5[bar_height,x_height]; z5=whatever[z2,z3];
  186. x6=1.5u; y6-.5stem=-oo; pos5(hair,theta-90); pos6(stem,angle(z5-z6)-90);
  187. filldraw circ_stroke z6e--z5e; % short diagonal
  188. penlabels(1,2,3,4,5,6); endchar;
  189.  
  190. cmchar "Lowercase Greek mu";
  191. beginchar(oct"026",9u#,x_height#,desc_depth#);
  192. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  193. adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
  194. pos1(stem,-180); pos2(stem,-180); x1=x2=x3; lft x1r=hround(1.5u-.5stem);
  195. y1+.5stem=h+oo; y2-.5stem=-d-o;
  196. filldraw z1r---z2r..z2l---z1l..cycle;  % left stem
  197. pos3(stem,-180); pos4(vair,-90); pos5(hair,0); x4=.5[x3,x5];
  198. pos6(stem,0); rt x6r=hround(w-2.5u+.5stem);
  199. x5=x6=x7; x9=w; hook_out(7,8,9);  % closing hook
  200. y3=.7[y4,y5]; bot y4r=-oo; y5=.57h; y6+.5stem=h;
  201. filldraw stroke super_arc.e(3,4)...{up}z5e; % left stem and arc
  202. filldraw circ_stroke z6e--z7e;  % right stem
  203. math_fit(desc_depth#*slant+.5stem#-u#,ic#);
  204. penlabels(1,2,3,4,5,6,7,8,9); endchar;
  205.  
  206. cmchar "Lowercase Greek nu";
  207. beginchar(oct"027",8.5u#,x_height#,0);
  208. italcorr x_height#*slant+.5stem#-u#;
  209. adjust_fit(0,0); pickup fine.nib;
  210. pos3(vair,-90); pos4(stem,0); bot y3r=0; y4+.5stem=h+oo;
  211. x3-.5stem=hround(1.5u-.5stem); x4+.5stem=hround(w-1.5u+.5stem);
  212. filldraw circ_stroke z4e{down}...{-36u,-h}z3e;  % diagonal
  213. pickup tiny.nib; pos1(stem,0); pos2(stem,0);
  214. top y1=h+min(oo,serif_drop); bot y2=0; x1=x2=x3;
  215. z=((z4{down}...{-36u,-h}z3)intersectionpoint((x2r,0)--(x2r,h)));
  216. filldraw z1l--z2l--z--z1r--cycle;  % stem
  217. sloped_serif.l(1,2,a,1/3,jut,serif_drop); % upper left serif
  218. math_fit(0,ic#-1/3x_height#*slant-.5u#); penlabels(1,2,3,4); endchar;
  219.  
  220. cmchar "Lowercase Greek xi";
  221. beginchar(oct"030",9u#,asc_height#,desc_depth#);
  222. italcorr .75[x_height#,asc_height#]*slant-2u#;
  223. adjust_fit(0,0); pickup fine.nib;
  224. pos10(hair,-720); pos11(vair,-630); pos12(hair,-540); pos13(vair,-450);
  225. lft x10l=hround 1/3w; x11=x13=.5[x10,x12]; rt x12l=hround(w-2.5u);
  226. top y10=h; top y13l=bot y11l+vstem+eps=vround(y10-.25(h-x_height));
  227. y12=.5[y11,y13]; if y11r>y13r: y11r:=y13r:=y12; fi
  228. pos0(curve,-360); pos1(vair,-270); pos2(hair,-180); pos3(vair,-90);
  229. numeric theta; theta=90-angle(22u,x_height); slope:=-x_height/22u;
  230. pos6(stem,theta); pos7(vair,-90); pos8(vair,-135);
  231. lft x0l=hround u; x1=x3=x11; x2=x12;
  232. y0=.5[y13,y1]; top y3l=vround .5h=bot y1l+vstem+eps; y2=.5[y1,y3];
  233. if y1r>y3r: y1r:=y3r:=y2; fi
  234. lft x4l=hround u; x4r-x4l=hround .5[vair,stem]-fine;
  235. x6=x7=w-2u; x8=.5w+.5u; y6=-.3d; bot y7r=-d-oo; y8=max(-3/4d-oo,y7l);
  236. ellipse_set(3l,4l,5l,6l); ellipse_set(3r,4r,5r,6r);
  237. y4l:=.9[y6,y4l]; y4=y4r:=.9[y6,y4r];
  238. filldraw circ_stroke z10e{down}...z11e{right}...{up}z12e;  % opening hook
  239. filldraw stroke z12e{up}...z13e{left}...z0e{down}
  240.  ...z1e{right}...{up}z2e;  % upper arc
  241. filldraw circ_stroke z8e{x7-x8,2(y7-y8)}...z7e{right}...z6e
  242.  ---z5e...{up}z4e...{right}z3e...{down}z2e;  % main stroke
  243. math_fit(-.2asc_height#*slant-.5u#,0);
  244. penlabels(0,1,2,3,4,5,6,7,8,10,11,12,13); endchar;
  245.  
  246. cmchar "Lowercase Greek pi";
  247. beginchar(oct"031",10u#,x_height#,0);
  248. italcorr x_height#*slant+.5stem#-u#;
  249. adjust_fit(0,0); pi_stroke; % hook and bar
  250. pos4(hair,0); pos6(hair,0); x4=3.5u; x6=w-4u; y4=y6=y2;
  251. x5=3u; x7=w-2.5u; y5=y7=.5stem-oo;
  252. pair v[]; v1=(z4-z5) xscaled 3.14159; v2=(z6-z7) xscaled 3.14159;
  253. pos5(stem,angle v1-90); pos7(stem,angle v2-90);
  254. filldraw circ_stroke z5e{v1}...{up}z4e;  % left stem
  255. filldraw circ_stroke z7e{v2}...{up}z6e;  % right stem
  256. math_fit(-.7x_height#*slant+.5hair#+.5u#,ic#-1/3x_height#*slant);
  257. penlabels(1,2,3,4,5,6,7); endchar;
  258.  
  259. cmchar "Lowercase Greek rho";
  260. beginchar(oct"032",8.25u#,x_height#,desc_depth#);
  261. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  262. adjust_fit(0,0); pickup fine.nib;
  263. pos1(stem,180); pos2(stem,180); pos3(vair,90);
  264. pos4(curve,0); pos5(vair,-90); pos6(hair,-180);
  265. lft x2r=hround(1.5u-.5stem); x1=x2=x6; x3=x5=.5[x2,x4];
  266. rt x4r=hround(w-1.5u+.5curve);
  267. y1-.5stem=-d-o; y2=y4=y6=.5[y3,y5]; top y3r=h+oo; bot y5r=-oo;
  268. filldraw circ_stroke z1e..pulled_arc.e(2,3) & pulled_arc.e(3,4)
  269.  & pulled_arc.e(4,5) & pulled_arc.e(5,6);  % stem and bowl
  270. math_fit(desc_depth#*slant+.5stem#-u#,ic#);
  271. penlabels(1,2,3,4,5,6); endchar;
  272.  
  273. cmchar "Lowercase Greek sigma";
  274. beginchar(oct"033",10.25u#,x_height#,0);
  275. italcorr x_height#*slant+.5stem#-u#;
  276. adjust_fit(0,0); pickup fine.nib;
  277. pos1(vstem,90); pos2(stem,0); pos3(vair,-90);
  278. pos4(stem,-180); pos5(vstem,-270); pos6(vstem,-270);
  279. x1=x3=x5=.5[x2,x4]; rt x2r=hround(w-2.5u);
  280. lft x4r=hround(1.5u-.5curve);x6=w-1.5u;
  281. top y1r=h; y2=y4=.5[y1,y3]; bot y3r=-oo; y5=y6=y1;
  282. filldraw circ_stroke z6e..pulled_arc.e(5,4) & pulled_arc.e(4,3)
  283.  & pulled_arc.e(3,2) & pulled_arc.e(2,1);  % ear and bowl
  284. math_fit(-.3x_height#*slant+.5curve#-u#,ic#-1/3x_height#*slant);
  285. penlabels(1,2,3,4,5,6); endchar;
  286.  
  287. cmchar "Lowercase Greek tau";
  288. beginchar(oct"034",9u#,x_height#,0);
  289. italcorr x_height#*slant+.5stem#-u#;
  290. adjust_fit(0,0); pi_stroke; % hook and bar
  291. pos4(hair,0); pos5(stem,0);
  292. x4=x5; x5-.5stem=hround(.5w-.5u-.5stem); y4=y2; y5-.5stem=-oo;
  293. filldraw circ_stroke z5e--z4e;  % stem
  294. math_fit(-.7x_height#*slant+.5hair#+.5u#,-.5u#);
  295. penlabels(1,2,3,4,5); endchar;
  296.  
  297. cmchar "Lowercase Greek upsilon";
  298. beginchar(oct"035",9u#,x_height#,0);
  299. italcorr x_height#*slant;
  300. adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
  301. x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  302. hook_in(0,1,2)(skewed);  % opening hook
  303. pos2'(stem,-180); z2'=z2; pos4(vair,-90); pos5(hair,0);
  304. x4=.5w+u; rt x5r=hround(w-.5u); y3=.7[y4,y5]; bot y4r=-oo; y5=.57h;
  305. filldraw stroke z2'e{-u,-x_height}...super_arc.e(3,4)
  306.  ..tension atleast 1.05..{up}z5e; % left stem and arc
  307. v_bulb(5,6);  % closing bulb
  308. math_fit(-2/3x_height#*slant+.5hair#+.5u#,2/3ic#);
  309. penlabels(0,1,2,3,4,5,6); endchar;
  310.  
  311. cmchar "Lowercase Greek phi";
  312. beginchar(oct"036",11u#,asc_height#,desc_depth#);
  313. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  314. adjust_fit(0,0); pickup fine.nib;
  315. numeric light_curve; light_curve=hround(.5[stem,curve]-2stem_corr);
  316. pos1(vair,90); pos2(light_curve,180); pos3(vair,270); pos4(light_curve,360);
  317. x1=x3=.5w; lft x2r=hround(1.5u-.5light_curve); x4=w-x2;
  318. top y1=x_height+oo; y2=y4=.5[y1,y3]; bot y3=-oo;
  319. filldraw stroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
  320.  & pulled_arc.e(3,4) & pulled_arc.e(4,1); % bowl
  321. pos5(hair,0); pos6(hair,0); x5=x6=.5w; top y5=h; bot y6=-d-oo;
  322. filldraw stroke z5e--z6e;  % stem
  323. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  324. penlabels(1,2,3,4,5,6); endchar;
  325.  
  326. cmchar "Lowercase Greek chi";
  327. beginchar(oct"037",11u#,x_height#,desc_depth#);
  328. italcorr x_height#*slant+.5hair#-1.5u#;
  329. adjust_fit(0,0); pickup fine.nib;
  330. pos1(hair,180); pos2(vair,80); pos5(vair,80); pos6(hair,180);
  331. x1-.5hair=hround-.5hair; x6=w-x1; x2=w-x5=u;
  332. y1=y2l-h/8; top y2r=h+oo; bot y5l=-d-oo; y6=y5r+h/8;
  333. z0=.5[z2,z5]; z2'=z2l+(.5u,0); z5'=z5r-(.5u,0);
  334. numeric theta; theta=angle(z5'-z2')+90;
  335. pos3(stem,theta); pos4(stem,theta);
  336. y3r=y2r-h/8; y4l=y5l+h/8; z3l=whatever[z2',z0]; z4r=whatever[z0,z5'];
  337. filldraw stroke z1e{up}...z2e{right}...z3e{z4r-z3l}
  338.  ..z4e{z4r-z3l}...{right}z5e...{up}z6e;  % major diagonal and hooks
  339. x8=w-x7=2u; y7+.5hair=h; y8-.5hair=-d;
  340. numeric theta; theta=angle(z7-z8)-90;
  341. pos7(hair,theta); pos8(hair,theta);
  342. filldraw z7l---z8l..z8r---z7r..cycle;  % minor diagonal
  343. math_fit((desc_depth#-x_height#)*slant+ic#,ic#);
  344. penlabels(0,1,2,2',3,4,5',5,6,7,8); endchar;
  345.  
  346. cmchar "Lowercase Greek psi";
  347. beginchar(oct"040",11u#,asc_height#,desc_depth#);
  348. italcorr x_height#*slant;
  349. adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
  350. x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  351. hook_in(0,1,2)(skewed);  % opening hook
  352. pos2'(stem,-180); z2'=z2; pos4(vair,-90); pos5(hair,0);
  353. x4=.5w+u; rt x5r=hround(w-.5u);
  354. y3=.7[y4,y5]; bot y4r=-oo; y5=.57x_height;
  355. filldraw stroke z2'e{-u,-x_height}...super_arc.e(3,4)
  356.  ..tension atleast 1.05..{up}z5e; % left stem and arc
  357. v_bulb(5,6);  % closing bulb
  358. pos7(hair,0); pos8(hair,0); x7=x8=.5w+.5u; top y7=h; bot y8=-d-oo;
  359. filldraw stroke z7e--z8e;  % stem
  360. math_fit(-2/3x_height#*slant+.5hair#+.5u#,2/3ic#);
  361. penlabels(0,1,2,3,4,5,6,7,8); endchar;
  362.  
  363. cmchar "Lowercase Greek omega";
  364. beginchar(oct"041",11u#,x_height#,0);
  365. italcorr x_height#*slant;
  366. adjust_fit(0,0); pickup fine.nib;
  367. pos2(hair,-180); lft x2r=hround.5u; y2=y4=y6=y8=bar_height;
  368. y1+.5hair=h; x1=x2+.75u; pos1(hair,angle(2(x1-x2),y1-y2)+90);
  369. pos3(vstem+dw,-90); pos4(hair,0); pos5(vair,90);
  370. pos6(hair,180); pos7(vstem+dw,270); pos8(hair,360);
  371. bot y3r=bot y7r=-oo; top y5r=vround(.2[y4,h]+.5vair);
  372. x3=.5[x2,x4]; x7+.25u=.5[x6,x8]; rt x8r=hround(w-.5u);
  373. x5+.5stem=hround(.5w+.5stem)+eps;
  374. x5=.5[x4,x6]; rt x4r-lft x6r=min(stem,2hair)+2eps;
  375. if x4l<x6l: x4l:=x6l:=x5; fi
  376. filldraw circ_stroke z1e{2(x2-x1),y2-y1}...z2e{down}...z3e{right}
  377.  ...{up}z4e...{left}z5e;  % left arc
  378. filldraw stroke z5e{left}...z6e{down}...z7e{right}...{up}z8e;  % right arc
  379. v_bulb(8,9);  % closing bulb
  380. math_fit(-bar_height#*slant,2/3ic#); penlabels(1,2,3,4,5,6,7,8,9); endchar;
  381.  
  382. cmchar "Variant lowercase Greek epsilon";
  383. beginchar(oct"042",8u#,x_height#,0);
  384. italcorr x_height#*slant-.5u#;
  385. adjust_fit(0,0); pickup fine.nib;
  386. numeric light_vstem; light_vstem=Vround 2/3[vair,vstem];
  387. pos2(light_vstem,90); x2=x8=.5w+.5u; top y2r=h+o;
  388. x1+.5light_vstem=hround(w-u); y1=.2[y2,bar_height];
  389. pos1(light_vstem,angle(x1-x2,2(y1-y2))+90); pos3(hair,180); pos4(vair,270);
  390. pos5(hair,360); pos6(vair,450); pos7(hair,540); pos8(light_vstem,630);
  391. lft x3r=hround u; x4=x6=.5w; rt x5r=hround(w-2.5u); x7=x3;
  392. y3=.5[y2,y4]; y5=bar_height=.5[y4,y6]; y7=.5[y6,y8]; bot y8r=-o;
  393. top y6r-bot y4r=vstem+eps; if y6l<y4l: y6l:=y4l:=y5; fi
  394. x9+.5vair=hround(w-.5u); y9=1/3[y8,bar_height];
  395. pos9(vair,angle(x8-x9,2(y8-y9))+90);
  396. filldraw circ_stroke z1e{x2-x1,2(y2-y1)}...pulled_super_arc.e(2,3)(.5superpull)
  397.  & super_arc.e(3,4)...{up}z5e;  % upper arc
  398. filldraw circ_stroke z9e{x8-x9,8(y8-y9)}...pulled_arc.e(8,7)
  399.  & super_arc.e(7,6)...{down}z5e;  % lower arc
  400. math_fit(-.5bar_height#*slant-.5u#,ic#);
  401. penlabels(1,2,3,4,5,6,7,8,9); endchar;
  402.  
  403. cmchar "Variant lowercase Greek theta";
  404. beginchar(oct"043",9u#,asc_height#,0);
  405. italcorr .5[bar_height#,x_height#]*slant+.5vair#+.5u#;
  406. adjust_fit(0,0); pickup fine.nib;
  407. numeric light_curve; light_curve=hround .5[stem,curve];
  408. x0=0; x2-.5stem=hround(2.5u-.5stem); hook_in(0,1,2);  % opening hook
  409. pos2'(stem,-180); z2'=z2; pos3(stem,-180); pos4(vair,-90);
  410. pos5(light_curve,0); pos6(vair,90); pos7(hair,180); pos8(vair,270);
  411. x3=x2; x4=x6=.5[x3,x5]; rt x5r=hround(w-1.5u+.5light_curve);
  412. lft x7r=hround(3.25u-.5hair); x8+.5vair=hround(w+.5vair-epsilon);
  413. y3=.4x_height; bot y4r=-oo; y5=.5[y4,y6]; top y6r=h+oo;
  414. y7=.5[x_height,h]; y8=.5[bar_height,x_height];
  415. filldraw stroke z2'e..{{interim superness:=hein_super; super_arc.e(3,4)}}
  416.  & pulled_arc.e(4,5) & pulled_arc.e(5,6)
  417.  ...{down}z7e...{4(x8-x7),y8-y7}z8e;  % bowl and loop
  418. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  419. penlabels(0,a,1,2,3,4,5,6,7,8); endchar;
  420.  
  421. cmchar "Variant lowercase Greek pi";
  422. beginchar(oct"044",14.5u#,x_height#,0);
  423. italcorr x_height#*slant+.5stem#-u#;
  424. adjust_fit(0,0); pi_stroke; % hook and bar
  425. pos4(hair,-180); pos5(hair,-180); pos6(vstem,-90);
  426. pos7(hair,0); pos7'(hair,-180); z7'=z7;
  427. pos8(vstem,-90); pos9(hair,0); pos0(hair,0);
  428. x4=x5+1.5u; lft x5r=hround 2u; x6=x4+.5u; lft x7l=hround(.5w+.25u-.5hair);
  429. x8=w-4.5u; rt x9r=hround(w-1.5u); x0=x9-1.25u;
  430. top y4=top y0=h; y5+.1h=y7-.1h=y9=bar_height; bot y6r=bot y8r=-oo;
  431. filldraw stroke z4e{2(x5-x4),y5-y4}...z5e{down}
  432.  ...z6e{right}...z7e{up};  % left bowl
  433. filldraw stroke z0e{2(x9-x0),y9-y0}...z9e{down}
  434.  ...z8e{left}...z7'e{up};  % right bowl
  435. math_fit(-.7x_height#*slant+.5hair#+.5u#,ic#-.5u#);
  436. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  437.  
  438. cmchar "Variant lowercase Greek rho";
  439. beginchar(oct"045",8.25u#,x_height#,desc_depth#);
  440. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  441. adjust_fit(0,0); pickup fine.nib;
  442. pos2(stem,180); pos3(vair,90); pos4(curve,0); pos5(vair,-90); pos6(stem,-180);
  443. lft x2r=hround(1.5u-.5stem); x2=x6; x3=x5=.5[x2,x4];
  444. rt x4r=hround(w-1.5u+.5curve);
  445. y2=y4=y6=.5[y3,y5]; top y3r=h+oo; bot y5r=-oo;
  446. filldraw circ_stroke pulled_arc.e(2,3) & pulled_arc.e(3,4)
  447.  & pulled_arc.e(4,5) & pulled_arc.e(5,6);  % bowl
  448. pos2'(hair,-180); z2'r=z2r; pos1(vstem,-90); pos1'(vstem,90); z1'=z1;
  449. pos0(hair,0); rt x0r=hround(w-u); bot y0=-d; bot y1r=vround-.9d; x1=x5;
  450. interim superness:=sqrt superness;
  451. filldraw stroke pulled_arc.e(0,1'); filldraw stroke pulled_arc.e(1,2'); % tail
  452. math_fit(desc_depth#*slant+.5stem#-u#,ic#);
  453. penlabels(0,1,2,3,4,5,6); endchar;
  454.  
  455. cmchar "Variant lowercase Greek sigma";
  456. beginchar(oct"046",8u#,x_height#,.5min(desc_depth#,.5x_height#));
  457. italcorr x_height#*slant-.5u#;
  458. adjust_fit(0,0); pickup fine.nib;
  459. numeric heavy_vair; heavy_vair=.25[vair,vstem];
  460. pos1(heavy_vair,-110); pos2(vair,-90);
  461. x1+.5heavy_vair=hround(w-u); y1=.1[y2r,bar_height];
  462. x2=min(.5w+u,x1r-eps); top y2l=h+oo;
  463. filldraw circ_stroke z1e{x2-x1,2(y2-y1)}...{left}z2e;  % upper bulb
  464. numeric theta; theta=90-angle(16u,x_height); slope:=-x_height/16u;
  465. pos6(stem,theta); pos7(vair,-90); pos8(vair,-135);
  466. lft x4l=hround u; x4r-x4l=(hround .5[vair,stem])-fine;
  467. x6=x7=w-2u; x8=.5w+u; y6=.25[y8,y2]; y8=y7+1/8d; bot y7r=-d-oo;
  468. ellipse_set(2l,4l,5l,6l); ellipse_set(2r,4r,5r,6r); y4=y4r;
  469. filldraw circ_stroke z8e{x7-x8,2(y7-y8)}...z7e{right}...z6e
  470.  ---z5e...{up}z4e...{right}z2e;  % main stroke
  471. math_fit(-.5x_height#*slant-.5u#,0); penlabels(1,2,4,5,6,7,8); endchar;
  472.  
  473. cmchar "Variant lowercase Greek phi";
  474. beginchar(oct"047",11u#,x_height#,desc_depth#);
  475. italcorr .7x_height#*slant;
  476. adjust_fit(0,0); pickup fine.nib;
  477. pos1(hair,-180); x1=x2+.75u; top y1=h;
  478. pos2(hair,-180); lft x2r=hround .5u; y2=bar_height;
  479. pos3(vstem,-90); x3=.5(w+u); bot y3r=-oo;
  480. pos4(hair,0); rt x4r=hround(w-.5u); y4=y2;
  481. pos5(vstem,90); x5=.52[x6,x4]; top y5r=h+oo;
  482. pos6(hair,180); x6=x7; y6=1/3h;
  483. pos7(stem,180); lft x7r=hround(.5w-.5u-.5stem); y7-.5stem=-d-o;
  484. filldraw circ_stroke z7e---z6e...{right}z5e...{down}z4e...{left}z3e
  485.  ...{up}z2e...{3(x1-x2),y1-y2}z1e;  % bowl and stem
  486. math_fit(-.3x_height#*slant,ic#); penlabels(1,2,3,4,5,6,7); endchar;
  487.